init

enemies/scripts/drop_data.gd

@@ -0,0 +1,15 @@
+class_name DropData extends Resource
+
+@export 
+var item: ItemData
+@export_range(0, 100, 1, "suffix:%")
+var drop_rate: float = 100
+@export_range(1, 10, 1, "suffix:items")
+var min_amount := 1
+@export_range(1, 10, 1, "suffix:items")
+var max_amount := 1
+
+func get_drop_count() -> int:
+	if randf_range(0, 100) >= drop_rate:
+		return 0
+	return randi_range(min_amount, max_amount)

enemies/scripts/drop_data.gd.uid

@@ -0,0 +1 @@
+uid://cqeos77b55w5x

enemies/scripts/enemy.gd

@@ -0,0 +1,67 @@
+class_name Enemy extends CharacterBody2D
+
+const DIR_4 = [
+	Vector2.RIGHT,
+	Vector2.DOWN,
+	Vector2.LEFT,
+	Vector2.UP,
+]
+
+signal direction_changed(new_direction: Vector2)
+signal enemy_damaged(hurtbox: Hurtbox)
+signal enemy_destroyed(hurtbox: Hurtbox)
+
+@export var hp: int = 3
+
+@onready var animation_player: AnimationPlayer = $AnimationPlayer
+@onready var main_sprite: Sprite2D = $main_sprite
+@onready var hitbox: Hitbox = $Hitbox
+@onready var state_machine: EnemyStateMachine = $enemy_state_machine
+
+var cardinal_direction : Vector2 = Vector2.DOWN
+var direction : Vector2 = Vector2.ZERO
+var invulnerable: bool = false
+
+func _ready() -> void:
+	state_machine.initialize(self)
+	hitbox.damaged.connect(on_damage)
+
+func _process(_delta: float) -> void:
+	pass
+
+func _physics_process(_delta: float) -> void:
+	move_and_slide()
+
+func set_direction(new_direction: Vector2) -> bool:
+	if new_direction == Vector2.ZERO:
+		return false
+
+	var refreshed_direction = DIR_4[int(round((new_direction + cardinal_direction * 0.1).angle() / TAU * DIR_4.size()))]
+
+	if refreshed_direction == cardinal_direction:
+		return false
+	cardinal_direction = refreshed_direction
+	direction_changed.emit(refreshed_direction)
+	main_sprite.scale.x = -1 if cardinal_direction == Vector2.LEFT else 1
+	return true
+
+func update_animation(state: String) -> void:
+	animation_player.play(state + "_" + get_animation_direction())
+
+func get_animation_direction() -> String:
+	var newAnimDirection: String = "side"
+	if cardinal_direction == Vector2.DOWN:
+		newAnimDirection = "down"
+	elif cardinal_direction == Vector2.UP:
+		newAnimDirection = "up"
+	return newAnimDirection
+
+func on_damage(hurtbox: Hurtbox) -> void:
+	if invulnerable:
+		return
+	hp -= hurtbox.damage
+	if hp > 0:
+		enemy_damaged.emit(hurtbox)
+	else:
+		enemy_destroyed.emit(hurtbox)
+

enemies/scripts/enemy.gd.uid

@@ -0,0 +1 @@
+uid://cmfpf1k80hvh7

enemies/scripts/enemy_state_machine.gd

@@ -0,0 +1,40 @@
+class_name EnemyStateMachine extends Node
+
+var states: Array[EnemyState]
+var previous_state: EnemyState
+var current_state: EnemyState
+
+func _ready() -> void:
+	process_mode = Node.PROCESS_MODE_DISABLED
+
+func _process(delta: float) -> void:
+	change_state(current_state.process(delta))
+
+func _physics_process(delta: float) -> void:
+	change_state(current_state.physics(delta))
+
+func initialize(enemy: Enemy) -> void:
+	states = []
+	for child in get_children():
+		if child is EnemyState:
+			states.append(child)
+
+	for state in states:
+		state.enemy = enemy
+		state.state_machine = self
+		state.init()
+
+	if !states.is_empty():
+		change_state(states[0])
+		process_mode = Node.PROCESS_MODE_INHERIT
+
+func change_state(new_state: EnemyState) -> void:
+	if new_state == null or new_state == current_state:
+		return
+
+	if current_state:
+		current_state.exit()
+	
+	previous_state = current_state
+	current_state = new_state
+	current_state.enter()

enemies/scripts/enemy_state_machine.gd.uid

@@ -0,0 +1 @@
+uid://bvjx5c5xd3rhw

enemies/scripts/states/enemy_state.gd

@@ -0,0 +1,20 @@
+class_name EnemyState extends Node
+
+var enemy: Enemy
+var state_machine: EnemyStateMachine
+
+func init() -> void:
+	pass
+
+func enter() -> void:
+	pass
+
+func exit() -> void:
+	pass
+
+func process(_delta : float) -> EnemyState:
+	return null
+
+func physics(_delta : float) -> EnemyState:
+	return null
+

enemies/scripts/states/enemy_state.gd.uid

@@ -0,0 +1 @@
+uid://u7qy2i6rutqr

enemies/scripts/states/enemy_state_chase.gd

@@ -0,0 +1,58 @@
+class_name EnemyChaseWander extends EnemyState
+
+@export var animation_name: String = "chase"
+@export var chase_speed: float = 20.0
+@export var turn_rate: float = 0.25
+
+@export_category("AI")
+@export var vision_area: VisionArea
+@export var attack_area: Hurtbox
+@export var state_aggro_duration: float = 0.5
+@export var next_state: EnemyState
+
+var timer: float = 0.0
+var direction: Vector2
+var can_see_player := false
+
+func init() -> void:
+	if vision_area:
+		vision_area.player_entered.connect(on_player_entered)
+		vision_area.player_exited.connect(on_player_exited)
+
+func enter() -> void:
+	timer = state_aggro_duration
+	enemy.update_animation(animation_name)
+	if attack_area:
+		attack_area.monitoring = true
+
+func exit() -> void:
+	if attack_area:
+		attack_area.monitoring = true
+	can_see_player = false
+
+func process(delta : float) -> EnemyState:
+	var new_dir: Vector2 = enemy.global_position.direction_to(PlayerManager.player.global_position)
+	direction = lerp(direction, new_dir, turn_rate)
+	enemy.velocity = direction * chase_speed
+	if enemy.set_direction(direction):
+		enemy.update_animation(animation_name)
+	if !can_see_player:
+		timer -= delta
+		if timer <= 0:
+			return next_state
+	else:
+		timer = state_aggro_duration
+	return null
+
+
+func physics(_delta : float) -> EnemyState:
+	return null
+
+func on_player_entered() -> void:
+	can_see_player = true
+	if state_machine.current_state is EnemyStateStun:
+		return
+	state_machine.change_state(self)
+
+func on_player_exited() -> void:
+	can_see_player = false

enemies/scripts/states/enemy_state_chase.gd.uid

@@ -0,0 +1 @@
+uid://dmcmplui6od1k

enemies/scripts/states/enemy_state_destroy.gd

@@ -0,0 +1,64 @@
+
+class_name EnemyStateDestroy extends EnemyState
+
+const PICKUP: Resource = preload("res://items/item_pickup/item_pickup.tscn")
+
+@export var animation_name: String = "destroy"
+@export var knockback_speed: float = 200.0
+@export var decelerate_speed: float = 10.0
+@export_category("Item drops")
+@export var drops: Array[DropData]
+
+var direction: Vector2
+var damage_position: Vector2
+
+func init() -> void:
+	enemy.enemy_destroyed.connect(on_destroyed)
+
+func enter() -> void:
+	enemy.invulnerable = true
+	enemy.animation_player.animation_finished.connect(on_animation_finished)
+	direction = enemy.global_position.direction_to(damage_position)
+	enemy.update_animation(animation_name)
+	enemy.set_direction(direction)
+	enemy.velocity = direction * -knockback_speed
+	disable_hurtbox()
+	drop_items()
+
+func exit() -> void:
+	enemy.invulnerable = false
+	enemy.animation_player.animation_finished.disconnect(on_animation_finished)
+
+func process(delta : float) -> EnemyState:
+	enemy.velocity -= enemy.velocity * decelerate_speed * delta
+	return null
+
+func physics(_delta : float) -> EnemyState:
+	return null
+
+func on_destroyed(hurtbox: Hurtbox) -> void:
+	state_machine.change_state(self)
+	damage_position = hurtbox.global_position
+
+func on_animation_finished(_name: String) -> void:
+	print("destroyed")
+	enemy.queue_free()
+
+func disable_hurtbox() -> void:
+	var hurtbox: Hurtbox = enemy.get_node_or_null("Hurtbox")
+	if hurtbox:
+		hurtbox.monitoring = false
+
+func drop_items() -> void:
+	if drops.is_empty():
+		return
+	for drops_index in drops.size():
+		var drop_item := drops[drops_index]
+		if drop_item and drop_item.item:
+			var drop_count := drop_item.get_drop_count()
+			for drop_index in drop_count:
+				var item_pickup := PICKUP.instantiate() as ItemPickup
+				item_pickup.item_data = drop_item.item
+				enemy.get_parent().call_deferred("add_child", item_pickup)
+				item_pickup.global_position = enemy.global_position
+				item_pickup.velocity = enemy.velocity.rotated(randf_range(-1.5, 1.5)) * randf_range(0.9, 1.5)

enemies/scripts/states/enemy_state_destroy.gd.uid

@@ -0,0 +1 @@
+uid://qn1vn11fqgui

enemies/scripts/states/enemy_state_idle.gd

@@ -0,0 +1,30 @@
+class_name EnemyStateIdle extends EnemyState
+
+@export var animation_name: String = "idle"
+
+@export_category("AI")
+@export var state_duration_min: float = 0.5
+@export var state_duration_max: float = 1.5
+@export var next_state: EnemyState
+
+var timer: float = 0.0
+
+func init() -> void:
+	pass
+
+func enter() -> void:
+	enemy.velocity = Vector2.ZERO
+	timer = randf_range(state_duration_min, state_duration_max)
+	enemy.update_animation(animation_name)
+
+func exit() -> void:
+	pass
+
+func process(delta : float) -> EnemyState:
+	timer -= delta
+	if timer <= 0:
+		return next_state
+	return null
+
+func physics(_delta : float) -> EnemyState:
+	return null

enemies/scripts/states/enemy_state_idle.gd.uid

@@ -0,0 +1 @@
+uid://t2wl0iif703e

enemies/scripts/states/enemy_state_stun.gd

@@ -0,0 +1,44 @@
+class_name EnemyStateStun extends EnemyState
+
+@export var animation_name: String = "stun"
+@export var knockback_speed: float = 200.0
+@export var decelerate_speed: float = 10.0
+
+@export_category("AI")
+@export var next_state: EnemyState
+
+var direction: Vector2
+var damage_position: Vector2
+var animation_finished: bool = false
+
+func init() -> void:
+	enemy.enemy_damaged.connect(on_damaged)
+
+func enter() -> void:
+	enemy.animation_player.animation_finished.connect(on_animation_finished)
+	enemy.invulnerable = true
+	animation_finished = false
+	direction = enemy.global_position.direction_to(damage_position)
+	enemy.update_animation(animation_name)
+	enemy.set_direction(direction)
+	enemy.velocity = direction * -knockback_speed
+
+func exit() -> void:
+	enemy.invulnerable = false
+	enemy.animation_player.animation_finished.disconnect(on_animation_finished)
+
+func process(delta : float) -> EnemyState:
+	if animation_finished:
+		return next_state
+	enemy.velocity -= enemy.velocity * decelerate_speed * delta
+	return null
+
+func physics(_delta : float) -> EnemyState:
+	return null
+
+func on_damaged(hurtbox: Hurtbox) -> void:
+	damage_position = hurtbox.global_position
+	state_machine.change_state(self)
+
+func on_animation_finished(_name: String) -> void:
+	animation_finished = true

enemies/scripts/states/enemy_state_stun.gd.uid

@@ -0,0 +1 @@
+uid://b6sf2nm67yulk

enemies/scripts/states/enemy_state_wander.gd

@@ -0,0 +1,38 @@
+class_name EnemyStateWander extends EnemyState
+
+@export var animation_name: String = "walk"
+@export var wander_speed: float = 20.0
+
+@export_category("AI")
+@export var state_animation_duration: float = 0.7
+@export var state_cycles_min: int = 1
+@export var state_cycles_max: int = 3
+@export var next_state: EnemyState
+
+var timer: float = 0.0
+var direction: Vector2
+
+func init() -> void:
+	pass
+
+func enter() -> void:
+	timer = randi_range(state_cycles_min, state_cycles_max) * state_animation_duration
+	var random_direction = randi_range(0, 3)
+	direction = enemy.DIR_4[random_direction]
+	enemy.velocity = direction * wander_speed
+	enemy.set_direction(direction)
+	enemy.update_animation(animation_name)
+
+func exit() -> void:
+	pass
+
+func process(delta : float) -> EnemyState:
+	timer -= delta
+	if timer <= 0:
+		return next_state
+	return null
+
+
+func physics(_delta : float) -> EnemyState:
+	return null
+

enemies/scripts/states/enemy_state_wander.gd.uid

@@ -0,0 +1 @@
+uid://dqiqly265lt0u

enemies/scripts/vision_area.gd

@@ -0,0 +1,33 @@
+class_name VisionArea extends Area2D
+
+signal player_entered
+signal player_exited
+
+func _ready() -> void:
+	body_entered.connect(on_body_entered)
+	body_exited.connect(on_body_exited)
+	var parent = get_parent()
+	if parent is Enemy:
+		parent.direction_changed.connect(on_direction_changed)
+
+func on_body_entered(body: Node2D) -> void:
+	if body is Player:
+		player_entered.emit()
+
+func on_body_exited(body: Node2D) -> void:
+	if body is Player:
+		player_exited.emit()
+
+func on_direction_changed(new_direction: Vector2) -> void:
+	match new_direction:
+		Vector2.DOWN:
+			rotation_degrees = 0
+		Vector2.UP:
+			rotation_degrees = 180
+		Vector2.LEFT:
+			rotation_degrees = 90
+		Vector2.RIGHT:
+			rotation_degrees = -90
+		_:
+			rotation_degrees = 0
+

enemies/scripts/vision_area.gd.uid

@@ -0,0 +1 @@
+uid://dumobb6c7eybb